エクセルで数値の順位を出せるRANK.EQ関数の使い方をご紹介します。 ランキングで並べ替える方法から、同順位が重なった場合の重複回避の手順もまとめました。 「上位3位までに自動で色を付ける」といった条件付き書式の活用法まで解説しているので、ぜひ参考にしてみてください。
順位を抽出する（RANK.EQ関数）
指定した「数値」が、「範囲」の中で何位なのかを「順序」に従って返します。
例：=RANK.EQ(B2,$B$2:$B$5,0)
【順序の種類】
- 0（省略時）：降順（大きい順）
- 1：昇順（小さい順）
💡 ポイント：範囲のみ「$」をつけて固定（例：$B$2:$B$5）します。
RANK.EQ関数の引数：(数値, 範囲, [順序])
📖 RANK.AVG関数との違い
- RANK.EQ：1位が2人いたら、二人とも「1位」とし、次は「3位」になります。
- RANK.AVG：1位が2人いたら、順位の平均である「1.5位」を返します。
順位で並び替える
Excel 2021以降の場合（SORT関数）
SORT関数を使って、「範囲」を指定した「列」の「順序」に従って並び替えます。
例：=SORT(A2:B5,2,-1)
【順序の種類】
- 1（省略時）：昇順（小さい順）
- -1：降順（大きい順）
SORT関数の引数：(範囲, [並べ替える列], [順序], [基準方向])
📖 詳しい解説は「SORT関数の使い方」の記事をご覧ください。
Excel 2019以前の場合（VLOOKUP関数）
【手順】
- データの左側に、RANK.EQ関数で「順位」の列を作成します。
- 任意の列（例：E）に、取り出したい順位（例：1～4）を入力します。
- 順位の隣（例：F）に以下のように入力し、オートフィルで数式をコピーします。
- 例：
=VLOOKUP(E2, $A$2:$C$5, 2, FALSE)
- 例：
💡 ポイント：検索範囲のみ「$」をつけて固定（例：$A$2:$C$5）します。
VLOOKUP関数の引数：(検索値, 検索範囲, 列番号, [検索の型])
📖 同順位がある場合の並び替え
VLOOKUP関数は「最初に見つけたデータ」を抽出するため、同順位があるとエラーが発生します。この問題を解決するために、「重複しない一意の順位」を作成します。
【手順】
順位を表示させたい列（例：A列）に、以下のような数式を入力します。
- 例：
=RANK.EQ(C2,$C$2:$C$5)+COUNTIF($C$2:C2,C2)-1
COUNTIF関数の引数：(検索範囲, 条件)
【数式の解説】
- RANK.EQ関数で、通常の順位を出します。
- COUNTIF関数で、「その値が範囲内に何回目に出現したか」をカウントします。
- 範囲の開始セルのみ固定（
$C$2:C2）することで、数式を下にコピーするたびに範囲が1行ずつ広がり、「自分より上に同じ値がいくつあるか」を数えられます。
- 範囲の開始セルのみ固定（
- 「順位」+「出現回数」-「1」します。
- 1回目に登場した値：
順位 + 1回目 - 1➡ 元の順位のまま - 2回目に登場した値：
順位 + 2回目 - 1➡ 次の順位へ繰り下げ
- 1回目に登場した値：
順位で色をつける（1～３位）
【手順1】
- 色付けしたい数値の範囲（例：A2:B5）を選択します
- 「ホーム」タブ→「条件付き書式」→「新しいルール」をクリックします。
【手順2】
- 「数式を使用して、書式設定するセルを決定」を選択し、以下のような数式を入力します。
- 1位に色をつける：
=RANK.EQ($B2,$B$2:$B$5,0)=1 - 3位まで色をつける：
=RANK.EQ($B2,$B$2:$B$5,0)<=3
- 1位に色をつける：
- 「書式」ボタンの「塗りつぶし」から好きな色を選び、「OK」を押します。
💡 ポイント：
- 数値：数値の1番上のセルを、列のみ絶対参照（例：$B2）で指定します。
- 範囲：数値の範囲を絶対参照（例：$B$2:$B$5）で指定します。
【1位・2位・3位を別々の色で分ける場合】
同じ範囲を選択したまま、順位ごとに新しいルールを3回作成します。
- 1位のルール：
=RANK.EQ($B2,$B$2:$B$5,0)=1➡ 赤色など - 2位のルール：
=RANK.EQ($B2,$B$2:$B$5,0)=2➡ 青色など - 3位のルール：
=RANK.EQ($B2,$B$2:$B$5,0)=3➡ 黄色など