【Excel】飛び飛びのセルを足し算する！

エクセルで「1行おき」や「指定した行間隔」で数値を合計する方法を解説します。 初心者でも簡単な「作業列とSUMIF関数」を使った方法から、MOD関数を使って複雑な間隔で合計する方法まで解説しているので、ぜひ参考にしてみてください。

1行おきに合計する（SUMIF関数）

【手順1】作業列を作る

1. 合計したい数値の隣の列に、作業列を作成します。
2. 目印となる文字（例：「○」や「1」）を入力し、合計したい間隔でコピーします。
   • 1行おき：目印のすぐ下のセルを「空白」にし、その2つのセルを選択してオートフィル。
   • 2行おき：目印の下に「2行の空白」を作り、その3つのセルを選択してオートフィル。

---

📖 下の行まで一気にコピーしたい場合：

1. 最初の目印と空白を選択し、Ctrl+Cでコピーします。
2. Ctrl+Shift+↓を押します。
3. 下まで選択状態になったら、Ctrl+Vで貼り付けます。

【手順2】目印の行だけ合計する

1. 合計を出したいセルに、以下のような数式を入力します。
   • 例：=SUMIF(A2:A5,"○",B2:B5)

💡 ポイント：条件が文字列の場合、ダブルクォーテーション（""）で囲います。

【数式の解説】

• 検索範囲（A列）から条件（○）を探し、一致した行にある合計範囲（B列）の数値だけを合計します。

1行おきに合計する（ISODD関数）

偶数行のみ合計する

指定した範囲のうち、シートの行番号が「偶数」のセルのみ合計します。

例：=SUM(IF(ISODD(ROW(A2:A5)), "", A2:A5))

💡 ポイント：Excel 2019以前の場合、Ctrl+Shift+Enterで確定します。

---

【数式の解説】

• ISODD関数：ROW関数の行番号が「奇数」の場合にTRUEを返します。
• IF関数：ISODD関数の結果がTRUEなら「空白」を、FALSEなら「数値」を返します。
• SUM関数：奇数は空白に置き換えられているため、偶数行のみ合計します。

奇数行のみ合計する

指定した範囲のうち、シートの行番号が「奇数」のセルのみ合計します。

例：=SUM(IF(ISODD(ROW(A2:A5)), A2:A5, ""))

💡 ポイント：Excel 2019以前の場合、Ctrl+Shift+Enterで確定します。

---

【数式の解説】

• ISODD関数：ROW関数の行番号が「奇数」の場合にTRUEを返します。
• IF関数：ISODD関数の結果がTRUEなら「数値」を、FALSEなら「空白」を返します。
• SUM関数：偶数は空白に置き換えられているため、奇数行のみ合計します。

2行おき・3行おきに合計する（MOD関数）

指定した範囲の1行目から、「2行おき」「3行おき」に合計します。

• 2行目（A2）から開始して、2行おき（3行に1回）に合計
  • 例：=SUM(IF(MOD(ROW(A2:A8)-2, 3)=0, A2:A8, ""))
• 2行目（A2）から開始して、3行おき（4行に1回）に合計
  • =SUM(IF(MOD(ROW(A2:A8)-2, 4)=0, A2:A8, ""))

💡 ポイント：Excel 2019以前の場合、Ctrl+Shift+Enterで確定します。

---

【開始行の調整】

ROW(範囲) - n の 「n」の部分を開始行と同じ数字にします。

• A2 から始めたい場合：ROW(A2:A100)-2
• A3 から始めたい場合：ROW(A3:A100)-3
• A5 から始めたい場合：ROW(A5:A100)-5